Ämne: Nibe 1245 visualisering av loggdata

[ulf68]

Med hjälp av Gnuplot kan man visualisera loggarna från sin Nibe pump.
Själv har jag använt det till att trimma gradminuter samt för framledning och köldbärare.

Skriptet nedan är kört med Gnuplot 4.4 på Windows. Ett tips är att ta bort raderna med rubriker från logfilen du får från pumpen. Skriptet förutsätter att loggning sker med 30s intervall (spelear roll för hur ackumulerad effekt räknas ut).

Resultatet blir en bild som visar temperatur och förbrukning för ett antal parametrar över tiden, bland annat ackumulerad förbrukning i kWh (så att du kan se dyngsförbrukningen hos pumpen).

Tyvärr sparar inte Nibe strömförbrukning per fas i loggen, annars skulle man få med även husets totala förbrukning över tiden.

Kodstycke: [Välj]

file_name = "110420-2.LOG"
set xrange [ "2011-04-27\t00:00:01":"2011-05-03\t23:59:59" ]
set title "Nibe 1245-6"
set style data fsteps
set xlabel "Date\nTime"
set timefmt "%Y-%m-%d\t%H:%M:%S"
set yrange [ -30 : 60 ]
set y2range [ 0 : 180 ]
set xdata time
set ylabel "Temperature"
set y2label "kWh"
set y2tics
set format x "%d-%H:%M"
set grid
set key above
rtu(x) = x/10
rtc(x) = x/100
acc_pow = 0
diff = 0
inc_pow(x, y) = acc_pow + (x<=6 ? 0 : 1350*30/3600) + (y*10*30/3600)
power(x)   = (x<=6 ? 0 : 100)
plot file_name using 1:(($17)==0?power($13):1/0) t 'kWh' axes x1y2 lc rgb '#F0F8E8' with boxes fs transparent, \
file_name using 1:(($17)>0?power($13):1/0) t 'kWh' axes x1y2 lc rgb '#B04848' with boxes fs transparent, \
file_name using 1:(rtu($4)) t 'Ute temp' lc rgb 'blue', \
file_name using 1:(rtu($20)) t 'Inne temp' lc rgb 'blue', \
     file_name using 1:(rtu($10)) t 'Önskad Framledning' lc rgb 'violet', \
     file_name using 1:(rtc($11)) t 'GM' lc rgb 'cyan', \
     file_name every 12 using 1:((($8-$9)<10 || ($8) > 50)?1/0:(($8-$9)>=28?($8+$9)/20:1/0)):($8)/10:($9)/10 t 'KB' with errorlines lc rgb 'green' , \
     file_name every 12 using 1:((($8-$9)<10 || ($8) > 50)?1/0:(($8-$9)<28?($8+$9)/20:1/0)):($8)/10:($9)/10 t 'KB' with errorlines lc rgb 'red' , \
     file_name using 1:(rtu($6)) t 'Framlednings temp' lc rgb 'green' , \
     file_name using 1:(($6-$7)/10) t 'Delta temp' lc rgb 'orange' , \
     file_name using 1:((acc_pow = inc_pow($13, $17))/1000) t 'kWh' axes x1y2 lc rgb 'red'
errorbars lc rgb '#003000' , \

print acc_pow
reset


[David Rinnan]

+1

[ulf68]

Efter att ha dragit upp värme kurvan ett snäpp under en vecka plockade jag ut en ny logg.
Kul att se hur den beter sig när det blir lite kallare också...

Tänkte förklara bilden lite mer den här gången.
Den övre mörkblå kurvan är loggad inomhus temperatur. Pumpen är inställd på att hålla 22ºC dagtid och 20ºC nattetid. Regleringen sker med hjälp av en innegivare. Anledningen till att ha innegivare istället för utegivare är att huset är välisolerat och har mycket fönster. Solen fixar en hel del av värmen, vilket man också ser på att pumpen vilar sig på dagarna. Innegivaren är också bra dom gånger jag eldar i kaminen.

Den röda kurvan som går från 0-64kWh är pumpens förbrukning under veckan. Den är uträknad på de riktvärden man hittar i Nibes dokumentation för deras 6 kW pump, dvs 1350W när pumpen går. Att ackumulera effektförbrukningen på det sättet stämmer rätt bra med vad fortum tycker i slutet av månaden. De perioder som pumpen går är markerat med ljusgröna staplar. Mitt i bilden ser man en röd stapel istället, vilket är det otäcka tillfälle då tillsatsen slår till (i det här fallet för att koka upp vattnet lite extra för att slippa att bakterier bosätter sig i varmvattenberedaren).

Gradminuter inställningen är satt på -90. Det är den ljusblå kurvan som pendlar mellan -9 och +10 på temperaturskalan (dvs den är skalad till en tiondel). Vid ett par tillfällen ser man att den dippar ned till -150-200, samtidigt som framlednings temperaturen spikar. Detta är vad som händer när man duschar en kall morgon, pumpen prioriterar varmvatten framför elementvärme. Driftsprioriteringen är inställd på 10 min elementvärme per 30 min.

Framlednings temperaturen är den gröna kurvan, som sågtandar sig runt den önskade framledningen (lila). Spikarna är varmvatten kokning. Man ser på kurvan att pumpen är av en typ som slår av och på (dvs inte är varvtals reglerad). När pumpen är på stiger framlednings temperaturen fort för att därefter klinga av när pumpen slår av.

Delta temperaturen (orange) slår mellan 0 och ca 8 grader. I pumpen regleras denna med hastigeten på cirkulationspumpen, långsammare pump gör att vattnet stannar längre i elementen och avger mer värme, vilket syns på en högre delta temperatur. Spikarna är även här vid omslag till varmvatten produktion.

Köldbärar temperaturen tänkte jag ta i ett senare inlägg, med en mer detaljerad bild.

[ulf68]

Det är smidigt att zooma i de bilder man skapar med skriptet, man ändrar bara den rad som börjar med "set xrange". I bilden nedan har jag zoomat in en dag.

Nu ser man lite bättre när pumpen går eller är av. Som man ser sköter sig den ganska fint, med tretton starter på en dag. Den längre sessionen mellan kl 6 och 8 är när pumpen går över till att jobba mot 22ºC (efter nattens 20ºC) samtidigt som en del varmvatten rinner ut i avloppet under duschen.

Det som är intressant i slutet av denna period ser man på deltavärdet för köldbärar temperaturen. Den visas med "errorbars" som är gröna när delta temperaturen är över det värde jag siktar på ( 2,8 ºC), och röda när är för låg. Det man ser är att pumpen suger värme ur hålet så att delta temperaturen minskar. Om jag skulle vilja trimma detta blir det genom att höja hastigheten på cirkulationspumpen för köldbäraren. Vid nästa period 20 min senare så är fin igen, så cirkulations pumpen får nog fortsätta med samma hastighet ett tag till.

För er som har andra loggande pumpar så funkar skriptet fint även för dessa. Det som behövs är loggdata i en textfil med datum och loggdata på varje rad. Om någon är intresserad kan jag zippa ihop en loggfil och skriptet i ett senare inlägg med lite användar handledning.

[David Rinnan]

Vid givet flöde kan minskat  på köldbäraren också vara en konsekvens av minskat effektuttag på grund av minskad verkningsgrad i samband med högre framledningstemperaturer, eller som du säger, lägre temp på inkommande köldbärare.